Moved PDDL example instances to subdirectory.

instances/PDDL/ipc-1998-gripper/domain.pddl

@@ -0,0 +1,34 @@
+(define (domain gripper-strips)
+   (:predicates (room ?r)
+		(ball ?b)
+		(gripper ?g)
+		(at-robby ?r)
+		(at ?b ?r)
+		(free ?g)
+		(carry ?o ?g))
+
+   (:action move
+       :parameters  (?from ?to)
+       :precondition (and  (room ?from) (room ?to) (at-robby ?from))
+       :effect (and  (at-robby ?to)
+		     (not (at-robby ?from))))
+
+
+
+   (:action pick
+       :parameters (?obj ?room ?gripper)
+       :precondition  (and  (ball ?obj) (room ?room) (gripper ?gripper)
+			    (at ?obj ?room) (at-robby ?room) (free ?gripper))
+       :effect (and (carry ?obj ?gripper)
+		    (not (at ?obj ?room)) 
+		    (not (free ?gripper))))
+
+
+   (:action drop
+       :parameters  (?obj  ?room ?gripper)
+       :precondition  (and  (ball ?obj) (room ?room) (gripper ?gripper)
+			    (carry ?obj ?gripper) (at-robby ?room))
+       :effect (and (at ?obj ?room)
+		    (free ?gripper)
+		    (not (carry ?obj ?gripper)))))
+

instances/PDDL/ipc-1998-gripper/problem-01.pddl

@@ -0,0 +1,22 @@
+(define (problem strips-gripper-x-1)
+   (:domain gripper-strips)
+   (:objects rooma roomb ball4 ball3 ball2 ball1 left right)
+   (:init (room rooma)
+          (room roomb)
+          (ball ball4)
+          (ball ball3)
+          (ball ball2)
+          (ball ball1)
+          (at-robby rooma)
+          (free left)
+          (free right)
+          (at ball4 rooma)
+          (at ball3 rooma)
+          (at ball2 rooma)
+          (at ball1 rooma)
+          (gripper left)
+          (gripper right))
+   (:goal (and (at ball4 roomb)
+               (at ball3 roomb)
+               (at ball2 roomb)
+               (at ball1 roomb))))

instances/PDDL/ipc-1998-gripper/problem-02.pddl

@@ -0,0 +1,28 @@
+(define (problem strips-gripper-x-2)
+   (:domain gripper-strips)
+   (:objects rooma roomb ball6 ball5 ball4 ball3 ball2 ball1 left right)
+   (:init (room rooma)
+          (room roomb)
+          (ball ball6)
+          (ball ball5)
+          (ball ball4)
+          (ball ball3)
+          (ball ball2)
+          (ball ball1)
+          (at-robby rooma)
+          (free left)
+          (free right)
+          (at ball6 rooma)
+          (at ball5 rooma)
+          (at ball4 rooma)
+          (at ball3 rooma)
+          (at ball2 rooma)
+          (at ball1 rooma)
+          (gripper left)
+          (gripper right))
+   (:goal (and (at ball6 roomb)
+               (at ball5 roomb)
+               (at ball4 roomb)
+               (at ball3 roomb)
+               (at ball2 roomb)
+               (at ball1 roomb))))

instances/PDDL/ipc-1998-gripper/solutions

@@ -0,0 +1,4 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-01.pddl | 11 | 384
+problem-02.pddl | 17 | 46080

instances/PDDL/ipc-2000-blocks-track-1-typed/domain.pddl

@@ -0,0 +1,49 @@
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;;; 4 Op-blocks world
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+
+(define (domain BLOCKS)
+  (:requirements :strips :typing)
+  (:types block)
+  (:predicates (on ?x - block ?y - block)
+	       (ontable ?x - block)
+	       (clear ?x - block)
+	       (handempty)
+	       (holding ?x - block)
+	       )
+
+  (:action pick-up
+	     :parameters (?x - block)
+	     :precondition (and (clear ?x) (ontable ?x) (handempty))
+	     :effect
+	     (and (not (ontable ?x))
+		   (not (clear ?x))
+		   (not (handempty))
+		   (holding ?x)))
+
+  (:action put-down
+	     :parameters (?x - block)
+	     :precondition (holding ?x)
+	     :effect
+	     (and (not (holding ?x))
+		   (clear ?x)
+		   (handempty)
+		   (ontable ?x)))
+  (:action stack
+	     :parameters (?x - block ?y - block)
+	     :precondition (and (holding ?x) (clear ?y))
+	     :effect
+	     (and (not (holding ?x))
+		   (not (clear ?y))
+		   (clear ?x)
+		   (handempty)
+		   (on ?x ?y)))
+  (:action unstack
+	     :parameters (?x - block ?y - block)
+	     :precondition (and (on ?x ?y) (clear ?x) (handempty))
+	     :effect
+	     (and (holding ?x)
+		   (clear ?y)
+		   (not (clear ?x))
+		   (not (handempty))
+		   (not (on ?x ?y)))))

instances/PDDL/ipc-2000-blocks-track-1-typed/problem-04-00.pddl

@@ -0,0 +1,7 @@
+(define (problem BLOCKS-4-0)
+(:domain BLOCKS)
+(:objects D B A C - block)
+(:INIT (CLEAR C) (CLEAR A) (CLEAR B) (CLEAR D) (ONTABLE C) (ONTABLE A)
+ (ONTABLE B) (ONTABLE D) (HANDEMPTY))
+(:goal (AND (ON D C) (ON C B) (ON B A)))
+)

instances/PDDL/ipc-2000-blocks-track-1-typed/problem-05-01.pddl

@@ -0,0 +1,7 @@
+(define (problem BLOCKS-5-1)
+(:domain BLOCKS)
+(:objects A D C E B - block)
+(:INIT (CLEAR B) (CLEAR E) (CLEAR C) (ONTABLE D) (ONTABLE E) (ONTABLE C)
+ (ON B A) (ON A D) (HANDEMPTY))
+(:goal (AND (ON D C) (ON C B) (ON B A) (ON A E)))
+)

instances/PDDL/ipc-2000-blocks-track-1-typed/problem-08-01.pddl

@@ -0,0 +1,7 @@
+(define (problem BLOCKS-8-1)
+(:domain BLOCKS)
+(:objects B A G C F D H E - block)
+(:INIT (CLEAR E) (CLEAR H) (CLEAR D) (CLEAR F) (ONTABLE C) (ONTABLE G)
+ (ONTABLE D) (ONTABLE F) (ON E C) (ON H A) (ON A B) (ON B G) (HANDEMPTY))
+(:goal (AND (ON C D) (ON D B) (ON B G) (ON G F) (ON F H) (ON H A) (ON A E)))
+)

instances/PDDL/ipc-2000-blocks-track-1-typed/problem-09-02.pddl

@@ -0,0 +1,8 @@
+(define (problem BLOCKS-9-2)
+(:domain BLOCKS)
+(:objects B I C E D A G F H - block)
+(:INIT (CLEAR H) (CLEAR F) (ONTABLE G) (ONTABLE F) (ON H A) (ON A D) (ON D E)
+ (ON E C) (ON C I) (ON I B) (ON B G) (HANDEMPTY))
+(:goal (AND (ON F G) (ON G H) (ON H D) (ON D I) (ON I E) (ON E B) (ON B C)
+            (ON C A)))
+)

instances/PDDL/ipc-2000-blocks-track-1-typed/solutions

@@ -0,0 +1,6 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-04-00.pddl | 6 | 1
+problem-05-01.pddl | 10 | 2
+problem-08-01.pddl | 20 | 60
+problem-09-02.pddl | 20 | 37

instances/PDDL/ipc-2000-elevator-m10-strips/domain.pddl

@@ -0,0 +1,66 @@
+(define (domain miconic)
+  (:requirements :strips)
+  (:types passenger - object
+          floor - object
+         )
+
+(:predicates 
+(origin ?person - passenger ?floor - floor)
+;; entry of ?person is ?floor
+;; inertia
+
+(destin ?person - passenger ?floor - floor)
+;; exit of ?person is ?floor
+;; inertia
+
+(above ?floor1 - floor  ?floor2 - floor)
+;; ?floor2 is located above of ?floor1
+
+(boarded ?person - passenger)
+;; true if ?person has boarded the lift
+
+(not-boarded ?person - passenger)
+;; true if ?person has not boarded the lift
+
+(served ?person - passenger)
+;; true if ?person has alighted as her destination
+
+(not-served ?person - passenger)
+;; true if ?person is not at their destination
+
+(lift-at ?floor - floor)
+;; current position of the lift is at ?floor
+)
+
+
+;;stop and allow boarding
+
+(:action board
+  :parameters (?f - floor ?p - passenger)
+  :precondition (and (lift-at ?f) (origin ?p ?f))
+  :effect (boarded ?p))
+
+(:action depart
+  :parameters (?f - floor ?p - passenger)
+  :precondition (and (lift-at ?f) (destin ?p ?f)
+		     (boarded ?p))
+  :effect (and (not (boarded ?p))
+	       (served ?p)))
+;;drive up
+
+(:action up
+  :parameters (?f1 - floor ?f2 - floor)
+  :precondition (and (lift-at ?f1) (above ?f1 ?f2))
+  :effect (and (lift-at ?f2) (not (lift-at ?f1))))
+
+
+;;drive down
+
+(:action down
+  :parameters (?f1 - floor ?f2 - floor)
+  :precondition (and (lift-at ?f1) (above ?f2 ?f1))
+  :effect (and (lift-at ?f2) (not (lift-at ?f1))))
+)
+
+
+

instances/PDDL/ipc-2000-elevator-m10-strips/problem-03-00.pddl

@@ -0,0 +1,58 @@
+
+
+
+(define (problem mixed-f6-p3-u0-v0-g0-a0-n0-A0-B0-N0-F0-r0)
+   (:domain miconic)
+   (:objects p0 p1 p2 - passenger
+             f0 f1 f2 f3 f4 f5 - floor)
+
+
+(:init
+(above f0 f1)
+(above f0 f2)
+(above f0 f3)
+(above f0 f4)
+(above f0 f5)
+
+(above f1 f2)
+(above f1 f3)
+(above f1 f4)
+(above f1 f5)
+
+(above f2 f3)
+(above f2 f4)
+(above f2 f5)
+
+(above f3 f4)
+(above f3 f5)
+
+(above f4 f5)
+
+
+
+(origin p0 f1)
+(destin p0 f4)
+
+(origin p1 f3)
+(destin p1 f1)
+
+(origin p2 f5)
+(destin p2 f1)
+
+
+
+
+
+
+(lift-at f0)
+)
+
+
+(:goal (and 
+(served p0)
+(served p1)
+(served p2)
+))
+)
+
+

instances/PDDL/ipc-2000-elevator-m10-strips/problem-03-01.pddl

@@ -0,0 +1,58 @@
+
+
+
+(define (problem mixed-f6-p3-u0-v0-g0-a0-n0-A0-B0-N0-F0-r1)
+   (:domain miconic)
+   (:objects p0 p1 p2 - passenger
+             f0 f1 f2 f3 f4 f5 - floor)
+
+
+(:init
+(above f0 f1)
+(above f0 f2)
+(above f0 f3)
+(above f0 f4)
+(above f0 f5)
+
+(above f1 f2)
+(above f1 f3)
+(above f1 f4)
+(above f1 f5)
+
+(above f2 f3)
+(above f2 f4)
+(above f2 f5)
+
+(above f3 f4)
+(above f3 f5)
+
+(above f4 f5)
+
+
+
+(origin p0 f2)
+(destin p0 f5)
+
+(origin p1 f5)
+(destin p1 f2)
+
+(origin p2 f4)
+(destin p2 f1)
+
+
+
+
+
+
+(lift-at f0)
+)
+
+
+(:goal (and 
+(served p0)
+(served p1)
+(served p2)
+))
+)
+
+

instances/PDDL/ipc-2000-elevator-m10-strips/problem-04-00.pddl

@@ -0,0 +1,77 @@
+
+
+
+(define (problem mixed-f8-p4-u0-v0-g0-a0-n0-A0-B0-N0-F0-r0)
+   (:domain miconic)
+   (:objects p0 p1 p2 p3 - passenger
+             f0 f1 f2 f3 f4 f5 f6 f7 - floor)
+
+
+(:init
+(above f0 f1)
+(above f0 f2)
+(above f0 f3)
+(above f0 f4)
+(above f0 f5)
+(above f0 f6)
+(above f0 f7)
+
+(above f1 f2)
+(above f1 f3)
+(above f1 f4)
+(above f1 f5)
+(above f1 f6)
+(above f1 f7)
+
+(above f2 f3)
+(above f2 f4)
+(above f2 f5)
+(above f2 f6)
+(above f2 f7)
+
+(above f3 f4)
+(above f3 f5)
+(above f3 f6)
+(above f3 f7)
+
+(above f4 f5)
+(above f4 f6)
+(above f4 f7)
+
+(above f5 f6)
+(above f5 f7)
+
+(above f6 f7)
+
+
+
+(origin p0 f7)
+(destin p0 f6)
+
+(origin p1 f1)
+(destin p1 f3)
+
+(origin p2 f1)
+(destin p2 f7)
+
+(origin p3 f2)
+(destin p3 f4)
+
+
+
+
+
+
+(lift-at f0)
+)
+
+
+(:goal (and 
+(served p0)
+(served p1)
+(served p2)
+(served p3)
+))
+)
+
+

instances/PDDL/ipc-2000-elevator-m10-strips/problem-04-01.pddl

@@ -0,0 +1,77 @@
+
+
+
+(define (problem mixed-f8-p4-u0-v0-g0-a0-n0-A0-B0-N0-F0-r1)
+   (:domain miconic)
+   (:objects p0 p1 p2 p3 - passenger
+             f0 f1 f2 f3 f4 f5 f6 f7 - floor)
+
+
+(:init
+(above f0 f1)
+(above f0 f2)
+(above f0 f3)
+(above f0 f4)
+(above f0 f5)
+(above f0 f6)
+(above f0 f7)
+
+(above f1 f2)
+(above f1 f3)
+(above f1 f4)
+(above f1 f5)
+(above f1 f6)
+(above f1 f7)
+
+(above f2 f3)
+(above f2 f4)
+(above f2 f5)
+(above f2 f6)
+(above f2 f7)
+
+(above f3 f4)
+(above f3 f5)
+(above f3 f6)
+(above f3 f7)
+
+(above f4 f5)
+(above f4 f6)
+(above f4 f7)
+
+(above f5 f6)
+(above f5 f7)
+
+(above f6 f7)
+
+
+
+(origin p0 f0)
+(destin p0 f5)
+
+(origin p1 f7)
+(destin p1 f4)
+
+(origin p2 f0)
+(destin p2 f7)
+
+(origin p3 f1)
+(destin p3 f6)
+
+
+
+
+
+
+(lift-at f0)
+)
+
+
+(:goal (and 
+(served p0)
+(served p1)
+(served p2)
+(served p3)
+))
+)
+
+

instances/PDDL/ipc-2000-elevator-m10-strips/solutions

@@ -0,0 +1,6 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-03-00.pddl | 10 | 12
+problem-03-01.pddl | 11 | 40
+problem-04-00.pddl | 14 | 180
+problem-04-01.pddl | 13 | 120

instances/PDDL/ipc-2002-depots-strips/domain.pddl

@@ -0,0 +1,42 @@
+(define (domain Depot)
+(:requirements :typing)
+(:types place locatable - object
+	depot distributor - place
+        truck hoist surface - locatable
+        pallet crate - surface)
+
+(:predicates (at ?x - locatable ?y - place) 
+             (on ?x - crate ?y - surface)
+             (in ?x - crate ?y - truck)
+             (lifting ?x - hoist ?y - crate)
+             (available ?x - hoist)
+             (clear ?x - surface))
+	
+(:action Drive
+:parameters (?x - truck ?y - place ?z - place) 
+:precondition (and (at ?x ?y))
+:effect (and (not (at ?x ?y)) (at ?x ?z)))
+
+(:action Lift
+:parameters (?x - hoist ?y - crate ?z - surface ?p - place)
+:precondition (and (at ?x ?p) (available ?x) (at ?y ?p) (on ?y ?z) (clear ?y))
+:effect (and (not (at ?y ?p)) (lifting ?x ?y) (not (clear ?y)) (not (available ?x)) 
+             (clear ?z) (not (on ?y ?z))))
+
+(:action Drop 
+:parameters (?x - hoist ?y - crate ?z - surface ?p - place)
+:precondition (and (at ?x ?p) (at ?z ?p) (clear ?z) (lifting ?x ?y))
+:effect (and (available ?x) (not (lifting ?x ?y)) (at ?y ?p) (not (clear ?z)) (clear ?y)
+		(on ?y ?z)))
+
+(:action Load
+:parameters (?x - hoist ?y - crate ?z - truck ?p - place)
+:precondition (and (at ?x ?p) (at ?z ?p) (lifting ?x ?y))
+:effect (and (not (lifting ?x ?y)) (in ?y ?z) (available ?x)))
+
+(:action Unload 
+:parameters (?x - hoist ?y - crate ?z - truck ?p - place)
+:precondition (and (at ?x ?p) (at ?z ?p) (available ?x) (in ?y ?z))
+:effect (and (not (in ?y ?z)) (not (available ?x)) (lifting ?x ?y)))
+
+)

instances/PDDL/ipc-2002-depots-strips/problem-01.pddl

@@ -0,0 +1,34 @@
+(define (problem depotprob1818) (:domain Depot)
+(:objects
+	depot0 - Depot
+	distributor0 distributor1 - Distributor
+	truck0 truck1 - Truck
+	pallet0 pallet1 pallet2 - Pallet
+	crate0 crate1 - Crate
+	hoist0 hoist1 hoist2 - Hoist)
+(:init
+	(at pallet0 depot0)
+	(clear crate1)
+	(at pallet1 distributor0)
+	(clear crate0)
+	(at pallet2 distributor1)
+	(clear pallet2)
+	(at truck0 distributor1)
+	(at truck1 depot0)
+	(at hoist0 depot0)
+	(available hoist0)
+	(at hoist1 distributor0)
+	(available hoist1)
+	(at hoist2 distributor1)
+	(available hoist2)
+	(at crate0 distributor0)
+	(on crate0 pallet1)
+	(at crate1 depot0)
+	(on crate1 pallet0)
+)
+
+(:goal (and
+		(on crate0 pallet2)
+		(on crate1 pallet1)
+	)
+))

instances/PDDL/ipc-2002-depots-strips/problem-02.pddl

@@ -0,0 +1,40 @@
+(define (problem depotprob7512) (:domain Depot)
+(:objects
+	depot0 - Depot
+	distributor0 distributor1 - Distributor
+	truck0 truck1 - Truck
+	pallet0 pallet1 pallet2 - Pallet
+	crate0 crate1 crate2 crate3 - Crate
+	hoist0 hoist1 hoist2 - Hoist)
+(:init
+	(at pallet0 depot0)
+	(clear crate0)
+	(at pallet1 distributor0)
+	(clear crate3)
+	(at pallet2 distributor1)
+	(clear crate2)
+	(at truck0 depot0)
+	(at truck1 depot0)
+	(at hoist0 depot0)
+	(available hoist0)
+	(at hoist1 distributor0)
+	(available hoist1)
+	(at hoist2 distributor1)
+	(available hoist2)
+	(at crate0 depot0)
+	(on crate0 pallet0)
+	(at crate1 distributor1)
+	(on crate1 pallet2)
+	(at crate2 distributor1)
+	(on crate2 crate1)
+	(at crate3 distributor0)
+	(on crate3 pallet1)
+)
+
+(:goal (and
+		(on crate0 pallet2)
+		(on crate1 crate3)
+		(on crate2 pallet0)
+		(on crate3 pallet1)
+	)
+))

instances/PDDL/ipc-2002-depots-strips/solutions

@@ -0,0 +1,4 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-01.pddl | 10 | 16
+problem-02.pddl | 15 | 448

instances/PDDL/ipc-2002-driver-log-strips/domain.pddl

@@ -0,0 +1,79 @@
+(define (domain driverlog)
+  (:requirements :typing) 
+  (:types         location locatable - object
+		driver truck obj - locatable
+  
+  )
+  (:predicates 
+		(at ?obj - locatable ?loc - location)
+		(in ?obj1 - obj ?obj - truck)
+		(driving ?d - driver ?v - truck)
+		(link ?x ?y - location) (path ?x ?y - location)
+		(empty ?v - truck)
+)
+
+
+(:action LOAD-TRUCK
+  :parameters
+   (?obj - obj
+    ?truck - truck
+    ?loc - location)
+  :precondition
+   (and (at ?truck ?loc) (at ?obj ?loc))
+  :effect
+   (and (not (at ?obj ?loc)) (in ?obj ?truck)))
+
+(:action UNLOAD-TRUCK
+  :parameters
+   (?obj - obj
+    ?truck - truck
+    ?loc - location)
+  :precondition
+   (and (at ?truck ?loc) (in ?obj ?truck))
+  :effect
+   (and (not (in ?obj ?truck)) (at ?obj ?loc)))
+
+(:action BOARD-TRUCK
+  :parameters
+   (?driver - driver
+    ?truck - truck
+    ?loc - location)
+  :precondition
+   (and (at ?truck ?loc) (at ?driver ?loc) (empty ?truck))
+  :effect
+   (and (not (at ?driver ?loc)) (driving ?driver ?truck) (not (empty ?truck))))
+
+(:action DISEMBARK-TRUCK
+  :parameters
+   (?driver - driver
+    ?truck - truck
+    ?loc - location)
+  :precondition
+   (and (at ?truck ?loc) (driving ?driver ?truck))
+  :effect
+   (and (not (driving ?driver ?truck)) (at ?driver ?loc) (empty ?truck)))
+
+(:action DRIVE-TRUCK
+  :parameters
+   (?truck - truck
+    ?loc-from - location
+    ?loc-to - location
+    ?driver - driver)
+  :precondition
+   (and (at ?truck ?loc-from)
+   (driving ?driver ?truck) (link ?loc-from ?loc-to))
+  :effect
+   (and (not (at ?truck ?loc-from)) (at ?truck ?loc-to)))
+
+(:action WALK
+  :parameters
+   (?driver - driver
+    ?loc-from - location
+    ?loc-to - location)
+  :precondition
+   (and (at ?driver ?loc-from) (path ?loc-from ?loc-to))
+  :effect
+   (and (not (at ?driver ?loc-from)) (at ?driver ?loc-to)))
+
+ 
+)

instances/PDDL/ipc-2002-driver-log-strips/problem-01.pddl

@@ -0,0 +1,48 @@
+(define (problem DLOG-2-2-2)
+	(:domain driverlog)
+	(:objects
+	driver1 - driver
+	driver2 - driver
+	truck1 - truck
+	truck2 - truck
+	package1 - obj
+	package2 - obj
+	s0 - location
+	s1 - location
+	s2 - location
+	p1-0 - location
+	p1-2 - location
+	)
+	(:init
+	(at driver1 s2)
+	(at driver2 s2)
+	(at truck1 s0)
+	(empty truck1)
+	(at truck2 s0)
+	(empty truck2)
+	(at package1 s0)
+	(at package2 s0)
+	(path s1 p1-0)
+	(path p1-0 s1)
+	(path s0 p1-0)
+	(path p1-0 s0)
+	(path s1 p1-2)
+	(path p1-2 s1)
+	(path s2 p1-2)
+	(path p1-2 s2)
+	(link s0 s1)
+	(link s1 s0)
+	(link s0 s2)
+	(link s2 s0)
+	(link s2 s1)
+	(link s1 s2)
+)
+	(:goal (and
+	(at driver1 s1)
+	(at truck1 s1)
+	(at package1 s0)
+	(at package2 s0)
+	))
+
+
+)

instances/PDDL/ipc-2002-driver-log-strips/problem-03.pddl

@@ -0,0 +1,59 @@
+(define (problem DLOG-2-2-4)
+	(:domain driverlog)
+	(:objects
+	driver1 - driver
+	driver2 - driver
+	truck1 - truck
+	truck2 - truck
+	package1 - obj
+	package2 - obj
+	package3 - obj
+	package4 - obj
+	s0 - location
+	s1 - location
+	s2 - location
+	p0-1 - location
+	p2-0 - location
+	p2-1 - location
+	)
+	(:init
+	(at driver1 s1)
+	(at driver2 s0)
+	(at truck1 s1)
+	(empty truck1)
+	(at truck2 s2)
+	(empty truck2)
+	(at package1 s0)
+	(at package2 s0)
+	(at package3 s1)
+	(at package4 s1)
+	(path s0 p0-1)
+	(path p0-1 s0)
+	(path s1 p0-1)
+	(path p0-1 s1)
+	(path s2 p2-0)
+	(path p2-0 s2)
+	(path s0 p2-0)
+	(path p2-0 s0)
+	(path s2 p2-1)
+	(path p2-1 s2)
+	(path s1 p2-1)
+	(path p2-1 s1)
+	(link s1 s0)
+	(link s0 s1)
+	(link s1 s2)
+	(link s2 s1)
+	(link s2 s0)
+	(link s0 s2)
+)
+	(:goal (and
+	(at driver2 s2)
+	(at truck1 s1)
+	(at truck2 s2)
+	(at package1 s1)
+	(at package2 s1)
+	(at package3 s2)
+	))
+
+
+)

instances/PDDL/ipc-2002-driver-log-strips/solutions

@@ -0,0 +1,4 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-01.pddl | 7 | 1
+problem-03.pddl | 12 | 1056

instances/PDDL/ipc-2004-satellite/domain.pddl

@@ -0,0 +1,75 @@
+
+(define (domain satellite)
+  (:requirements :strips :equality :typing)
+  (:types satellite direction instrument mode)
+ (:predicates 
+               (on_board ?i - instrument ?s - satellite)
+	       (supports ?i - instrument ?m - mode)
+	       (pointing ?s - satellite ?d - direction)
+	       (power_avail ?s - satellite)
+	       (power_on ?i - instrument)
+	       (calibrated ?i - instrument)
+	       (have_image ?d - direction ?m - mode)
+	       (calibration_target ?i - instrument ?d - direction))
+ 
+ 
+
+  (:action turn_to
+   :parameters (?s - satellite ?d_new - direction ?d_prev - direction)
+   :precondition (and (pointing ?s ?d_prev)
+              )
+   :effect (and  (pointing ?s ?d_new)
+                 (not (pointing ?s ?d_prev))
+           )
+  )
+
+ 
+  (:action switch_on
+   :parameters (?i - instrument ?s - satellite)
+ 
+   :precondition (and (on_board ?i ?s) 
+                      (power_avail ?s)
+                 )
+   :effect (and (power_on ?i)
+                (not (calibrated ?i))
+                (not (power_avail ?s))
+           )
+          
+  )
+
+ 
+  (:action switch_off
+   :parameters (?i - instrument ?s - satellite)
+ 
+   :precondition (and (on_board ?i ?s)
+                      (power_on ?i) 
+                  )
+   :effect (and (not (power_on ?i))
+                (power_avail ?s)
+           )
+  )
+
+  (:action calibrate
+   :parameters (?s - satellite ?i - instrument ?d - direction)
+   :precondition (and (on_board ?i ?s)
+		      (calibration_target ?i ?d)
+                      (pointing ?s ?d)
+                      (power_on ?i)
+                  )
+   :effect (calibrated ?i)
+  )
+
+
+  (:action take_image
+   :parameters (?s - satellite ?d - direction ?i - instrument ?m - mode)
+   :precondition (and (calibrated ?i)
+                      (on_board ?i ?s)
+                      (supports ?i ?m)
+                      (power_on ?i)
+                      (pointing ?s ?d)
+                      (power_on ?i)
+               )
+   :effect (have_image ?d ?m)
+  )
+)
+

instances/PDDL/ipc-2004-satellite/problem-01.pddl

@@ -0,0 +1,30 @@
+(define (problem strips-sat-x-1)
+(:domain satellite)
+(:objects
+	satellite0 - satellite
+	instrument0 - instrument
+	image1 - mode
+	spectrograph2 - mode
+	thermograph0 - mode
+	Star0 - direction
+	GroundStation1 - direction
+	GroundStation2 - direction
+	Phenomenon3 - direction
+	Phenomenon4 - direction
+	Star5 - direction
+	Phenomenon6 - direction
+)
+(:init
+	(supports instrument0 thermograph0)
+	(calibration_target instrument0 GroundStation2)
+	(on_board instrument0 satellite0)
+	(power_avail satellite0)
+	(pointing satellite0 Phenomenon6)
+)
+(:goal (and
+	(have_image Phenomenon4 thermograph0)
+	(have_image Star5 thermograph0)
+	(have_image Phenomenon6 thermograph0)
+))
+
+)

instances/PDDL/ipc-2004-satellite/problem-02.pddl

@@ -0,0 +1,40 @@
+(define (problem strips-sat-x-1)
+(:domain satellite)
+(:objects
+	satellite0 - satellite
+	instrument0 - instrument
+	instrument1 - instrument
+	infrared0 - mode
+	infrared1 - mode
+	image2 - mode
+	GroundStation1 - direction
+	Star0 - direction
+	GroundStation2 - direction
+	Planet3 - direction
+	Planet4 - direction
+	Phenomenon5 - direction
+	Phenomenon6 - direction
+	Star7 - direction
+)
+(:init
+	(supports instrument0 infrared1)
+	(supports instrument0 infrared0)
+	(calibration_target instrument0 Star0)
+	(supports instrument1 image2)
+	(supports instrument1 infrared1)
+	(supports instrument1 infrared0)
+	(calibration_target instrument1 GroundStation2)
+	(on_board instrument0 satellite0)
+	(on_board instrument1 satellite0)
+	(power_avail satellite0)
+	(pointing satellite0 Planet4)
+)
+(:goal (and
+	(have_image Planet3 infrared0)
+	(have_image Planet4 infrared0)
+	(have_image Phenomenon5 image2)
+	(have_image Phenomenon6 infrared0)
+	(have_image Star7 infrared0)
+))
+
+)

instances/PDDL/ipc-2004-satellite/problem-03.pddl

@@ -0,0 +1,52 @@
+(define (problem strips-sat-x-1)
+(:domain satellite)
+(:objects
+	satellite0 - satellite
+	instrument0 - instrument
+	instrument1 - instrument
+	instrument2 - instrument
+	satellite1 - satellite
+	instrument3 - instrument
+	image1 - mode
+	infrared0 - mode
+	spectrograph2 - mode
+	Star1 - direction
+	Star2 - direction
+	Star0 - direction
+	Star3 - direction
+	Star4 - direction
+	Phenomenon5 - direction
+	Phenomenon6 - direction
+	Phenomenon7 - direction
+)
+(:init
+	(supports instrument0 spectrograph2)
+	(supports instrument0 infrared0)
+	(calibration_target instrument0 Star1)
+	(supports instrument1 image1)
+	(calibration_target instrument1 Star2)
+	(supports instrument2 infrared0)
+	(supports instrument2 image1)
+	(calibration_target instrument2 Star0)
+	(on_board instrument0 satellite0)
+	(on_board instrument1 satellite0)
+	(on_board instrument2 satellite0)
+	(power_avail satellite0)
+	(pointing satellite0 Star4)
+	(supports instrument3 spectrograph2)
+	(supports instrument3 infrared0)
+	(supports instrument3 image1)
+	(calibration_target instrument3 Star0)
+	(on_board instrument3 satellite1)
+	(power_avail satellite1)
+	(pointing satellite1 Star0)
+)
+(:goal (and
+	(pointing satellite0 Phenomenon5)
+	(have_image Star3 infrared0)
+	(have_image Star4 spectrograph2)
+	(have_image Phenomenon5 spectrograph2)
+	(have_image Phenomenon7 spectrograph2)
+))
+
+)

instances/PDDL/ipc-2004-satellite/solutions

@@ -0,0 +1,5 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-01.pddl | 9 | 12
+problem-02.pddl | 13 | 240
+problem-03.pddl | 11 | 276

instances/PDDL/ipc-2006-tpp-propositional/domain.pddl

@@ -0,0 +1,65 @@
+; IPC5 Domain: TPP Propositional
+; Authors: Alfonso Gerevini and Alessandro Saetti 
+
+(define (domain TPP-Propositional)
+(:requirements :strips :typing)
+(:types place locatable level - object
+	depot market - place
+	truck goods - locatable)
+
+(:predicates (loaded ?g - goods ?t - truck ?l - level)
+	     (ready-to-load ?g - goods ?m - market ?l - level) 
+	     (stored ?g - goods ?l - level) 
+	     (on-sale ?g - goods ?m -  market ?l - level)
+	     (next ?l1 ?l2 - level)
+	     (at ?t - truck ?p - place)
+	     (connected ?p1 ?p2 - place))
+
+(:action drive
+ :parameters (?t - truck ?from ?to - place)
+ :precondition (and (at ?t ?from) (connected ?from ?to))
+ :effect (and (not (at ?t ?from)) (at ?t ?to)))
+
+
+; ### LOAD ###
+; ?l1 is the level of ?g ready to be loaded at ?m before loading
+; ?l2 is the level of ?g ready to be loaded at ?m after loading
+; ?l3 is the level of ?g in ?t before loading
+; ?l4 is the level of ?g in ?t after loading
+
+(:action load
+ :parameters (?g - goods ?t - truck ?m - market ?l1 ?l2 ?l3 ?l4 - level)
+ :precondition (and (at ?t ?m) (loaded ?g ?t ?l3)
+		    (ready-to-load ?g ?m ?l2) (next ?l2 ?l1) (next ?l4 ?l3))
+ :effect (and (loaded ?g ?t ?l4) (not (loaded ?g ?t ?l3)) 
+	      (ready-to-load ?g ?m ?l1) (not (ready-to-load ?g ?m ?l2))))
+
+
+; ### UNLOAD ###
+; ?l1 is the level of ?g in ?t before unloading
+; ?l2 is the level of ?g in ?t after unloading
+; ?l3 is the level of ?g in ?d before unloading
+; ?l4 is the level of ?g in ?d after unloading
+
+(:action unload
+ :parameters (?g - goods ?t - truck ?d - depot ?l1 ?l2 ?l3 ?l4 - level)
+ :precondition (and (at ?t ?d) (loaded ?g ?t ?l2)
+		    (stored ?g ?l3) (next ?l2 ?l1) (next ?l4 ?l3))
+ :effect (and (loaded ?g ?t ?l1) (not (loaded ?g ?t ?l2)) 
+	      (stored ?g ?l4) (not (stored ?g ?l3))))
+
+
+; ### BUY ###
+; ?l1 is the level of ?g on sale at ?m before buying
+; ?l2 is the level of ?g on sale at ?m after buying 
+; ?l3 is the level of ?g ready to be loaded at ?m before buying
+; ?l4 is the level of ?g ready to be loaded at ?m after buying
+
+(:action buy
+ :parameters (?t - truck ?g - goods ?m - market ?l1 ?l2 ?l3 ?l4 - level)
+ :precondition (and (at ?t ?m) (on-sale ?g ?m ?l2) (ready-to-load ?g ?m ?l3)
+		    (next ?l2 ?l1) (next ?l4 ?l3))
+ :effect (and (on-sale ?g ?m ?l1) (not (on-sale ?g ?m ?l2)) 
+	      (ready-to-load ?g ?m ?l4) (not (ready-to-load ?g ?m ?l3))))
+
+)

instances/PDDL/ipc-2006-tpp-propositional/problem-02.pddl

@@ -0,0 +1,28 @@
+(define (problem TPP)
+(:domain TPP-Propositional)
+(:objects
+	goods1 goods2 - goods
+	truck1 - truck
+	market1 - market
+	depot1 - depot
+	level0 level1 - level)
+
+(:init
+	(next level1 level0)
+	(ready-to-load goods1 market1 level0)
+	(ready-to-load goods2 market1 level0)
+	(stored goods1 level0)
+	(stored goods2 level0)
+	(loaded goods1 truck1 level0)
+	(loaded goods2 truck1 level0)
+	(connected depot1 market1)
+	(connected market1 depot1)
+	(on-sale goods1 market1 level1)
+	(on-sale goods2 market1 level1)
+	(at truck1 depot1))
+
+(:goal (and
+	(stored goods1 level1)
+	(stored goods2 level1)))
+
+)

instances/PDDL/ipc-2006-tpp-propositional/problem-03.pddl

@@ -0,0 +1,33 @@
+(define (problem TPP)
+(:domain TPP-Propositional)
+(:objects
+	goods1 goods2 goods3 - goods
+	truck1 - truck
+	market1 - market
+	depot1 - depot
+	level0 level1 - level)
+
+(:init
+	(next level1 level0)
+	(ready-to-load goods1 market1 level0)
+	(ready-to-load goods2 market1 level0)
+	(ready-to-load goods3 market1 level0)
+	(stored goods1 level0)
+	(stored goods2 level0)
+	(stored goods3 level0)
+	(loaded goods1 truck1 level0)
+	(loaded goods2 truck1 level0)
+	(loaded goods3 truck1 level0)
+	(connected depot1 market1)
+	(connected market1 depot1)
+	(on-sale goods1 market1 level1)
+	(on-sale goods2 market1 level1)
+	(on-sale goods3 market1 level1)
+	(at truck1 depot1))
+
+(:goal (and
+	(stored goods1 level1)
+	(stored goods2 level1)
+	(stored goods3 level1)))
+
+)

instances/PDDL/ipc-2006-tpp-propositional/problem-04.pddl

@@ -0,0 +1,38 @@
+(define (problem TPP)
+(:domain TPP-Propositional)
+(:objects
+	goods1 goods2 goods3 goods4 - goods
+	truck1 - truck
+	market1 - market
+	depot1 - depot
+	level0 level1 - level)
+
+(:init
+	(next level1 level0)
+	(ready-to-load goods1 market1 level0)
+	(ready-to-load goods2 market1 level0)
+	(ready-to-load goods3 market1 level0)
+	(ready-to-load goods4 market1 level0)
+	(stored goods1 level0)
+	(stored goods2 level0)
+	(stored goods3 level0)
+	(stored goods4 level0)
+	(loaded goods1 truck1 level0)
+	(loaded goods2 truck1 level0)
+	(loaded goods3 truck1 level0)
+	(loaded goods4 truck1 level0)
+	(connected depot1 market1)
+	(connected market1 depot1)
+	(on-sale goods1 market1 level1)
+	(on-sale goods2 market1 level1)
+	(on-sale goods3 market1 level1)
+	(on-sale goods4 market1 level1)
+	(at truck1 depot1))
+
+(:goal (and
+	(stored goods1 level1)
+	(stored goods2 level1)
+	(stored goods3 level1)
+	(stored goods4 level1)))
+
+)

instances/PDDL/ipc-2006-tpp-propositional/solutions

@@ -0,0 +1,5 @@
+instance | minimal horizon | #solutions with minimal horizon
+============================================================
+problem-02.pddl | 8 | 12
+problem-03.pddl | 11 | 540
+problem-04.pddl | 14 | 60480