patrick/plasp
Archived
1
0
Fork 0
Code Issues 12 Releases 8 Activity

optional redundant rules to reduce the number of parallel plans

Browse Source
This commit is contained in:
mgebser 2016-11-15 18:57:52 +01:00
parent 03c83702ad
commit f12ac1c839
1 changed files with 24 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

24
encodings/strips/redundancy.lp Normal file
View File

@ -0,0 +1,24 @@
% Additional rules for enforcing the inclusion of parallel actions in plans,
% whenever such 'redundant' actions are compatible with states and other actions
#program step(t).
defeated(A,t) :- active(A), postcondition(A,X,V), fluent(X), not holds(X,V,t),
_parallel = 1 : _parallel != 2.
defeated(A,t) :- _parallel = 1, active(A), precondition(A,X,V), not holds(X,V,t-1).
defeated(A,t) :- _parallel = 1, active(A), precondition(A,X,V), not holds(X,V,t).
defeated(A,t) :- _parallel = 1, active(A), postcondition(A,X,V), not precondition(A,X,V),
single(X,t).
proceed(A,X,V,t) :- active(A), holds(X,V,t-1), scope(X,V).
proceed(A,X,V,t) :- active(A), occurs(A1,t), perform(A,A1,t), A != A1,
postcondition(A1,X,V), scope(X,V), not precondition(A1,X,V).
perform(A,A1,t) :- active(A), active(A1), A != A1, _parallel = 2, not occurs(A1,t).
perform(A,A1,t) :- active(A), active(A1), _parallel = 2,
proceed(A,X,V,t) : precondition(A1,X,V); perform(A,A2,t) : disable(A1,A2).
defeated(A,t) :- _parallel = 2, active(A), not perform(A,A,t).
:- active(A), not occurs(A,t), not defeated(A,t), _parallel = 1 : _parallel != 2.